Derelict — 3 of 10

Chapter 1 - World Ruleset and Map Layout

Fore is a direction. Aft is a direction. The opposite of fore is aft. The opposite of aft is fore.

Port is a direction. Starboard is a direction. The opposite of port is starboard. The opposite of starboard is port.

Understand "f" as fore.

Understand "a" and "af" as aft.

Understand "p" as port.

Understand "sb" as starboard.

Index map with fore mapped as north. Index map with aft mapped as south. Index map with port mapped as west. Index map with starboard mapped as east.

EncounterFreq is a number variable and 8.

EncounterCount is a number variable and 0.

BodyCount is a number variable and 3.

Vlog4access is a number variable and 0.

Vlog7access is a number variable and 0.

ConsoleInRoom is a number variable and 0.

Every turn:

if a console is in the location of the player:

now ConsoleInRoom is 1;

else:

now ConsoleInRoom is 0;

Instead of going South: say "Your suit's built-in compass is for terrestrial exploration; there's no magnetic field in space.".

Instead of going North: say "Your suit's built-in compass is for terrestrial exploration; there's no magnetic field in space.".

Instead of going East: say "Your suit's built-in compass is for terrestrial exploration; there's no magnetic field in space.".

Instead of going West: say "Your suit's built-in compass is for terrestrial exploration; there's no magnetic field in space.".

Instead of going Southwest: say "Your suit's built-in compass is for terrestrial exploration; there's no magnetic field in space.".

Instead of going Northwest: say "Your suit's built-in compass is for terrestrial exploration; there's no magnetic field in space.".

Instead of going Southeast: say "Your suit's built-in compass is for terrestrial exploration; there's no magnetic field in space.".

Instead of going Northeast: say "Your suit's built-in compass is for terrestrial exploration; there's no magnetic field in space.".

Display Map is an action applying to nothing.

Understand "map" as Display Map.

Carry out Display Map:

display the Figure Map.

Figure Map is the file "Map.jpg".

UseConsole is an action applying to nothing.

Understand "use console" or "use computer" or "use computer console" as UseConsole.

Check UseConsole:

if ConsoleInRoom is 0:

say "There is no console in this room." instead.

Carry out UseConsole:

run a conversation on the Table of Computer Interactions.

TalkHerman is an action applying to nothing.

Understand "talk to herman" or "talk to ai" as TalkHerman.

Check TalkHerman:

if the player is not in Engineering:

say "You need to be in Engineering to talk to Herman." instead.

Carry out TalkHerman:

say "'Yes? How may I help you?";

if vlog4access is 1:

Enable the hermsec1 quip;

Enable the hermdeathtrue quip;

run a conversation on the Table of Herman Interactions.

[Top floor]

The Captain's Quarters is a room. The Captain's Quarters is port of Communications. "The Captain's Quarters is a room of luxury. Even though the Captain doesn't actually get to spend much time here, it is Federation standard that their quarters are a place they can retreat to for relaxation and decompression. But not explosive decompression. That would be bad.[line break][line break]Communications is starboard of here, and the Lift shaft is aft."

The Dining Hall is a room. The Dining Hall is aft of Communications. "The Dining Hall is a typical cafeteria, with a kitchen to prepare and a buffet style line for serving the crappy spacefare available.[line break][line break]Communications is fore of here. The Lift shaft is portside."

Communications is a room. Communications is aft of the B Door. "The Communications room is fairly self explanatory, but if you really need a detailed description... there are devices here for communicating. Most of the technology is nothing complicated, RADAR, X-RAY, infrared sensors, as well as an array of ultra long range radios. Multiple consoles form an array around the border of the room.[line break][line break]The Dining Hall is aft of here, the Bridge is fore, and the Captain's Quarters is port."

The Bridge is a room. The Bridge is fore of the B Door. "The bridge is where the ship is commanded and piloted from. It has a large bay window facing into the abyss of space, though it's usually covered by much more useful projection screens. It is situated quite like a conference room, with the Captain's chair at the head of an elliptical table facing the window, with the various department heads having their designated seats around the long sides. An untrained witness of the ship running at full steam could easily mistake it for a board meeting. Computer consoles are built into the surface of the table. [line break][line break]Communications is aft of here."

[Second floor]

The Cryostasis Hold is a room. "The Cryostasis Hold is designed for keeping passengers from aging (or getting bored) during long space flights. Generally, the crew can also go into periods of Cryostasis allowing the AI to handle the day to day management of the ship, however, as this was also a research voyage, there are only enough pods for the passengers. You look around at the names labling the various pods, but none of them seem familiar, even the one labling the pod you stepped out of.[if the Locker is in the Cryostasis Hold] There is a [locker] next to each of the pods, but only the one next to your pod is open.[end if][line break][line break]The Commons is fore of here."

The Commons is a room. The Cryostasis Hold is aft of the Commons. The Commons is fore of the Cryostasis Hold. "The Common area has a few couches, pool and foosball tables, as well as a projector. The projector is attached to a holodisk player with a small selection of physical disks as well as a hard drive containing a much wider selection of programming, though most of that has been censored by the military. The passengers and crew tend to enjoy their personal copies of 'It Came From Planet 10 in the Outer Rim' more than the digital '__ Came From _____ in the ______.' A Computer console lies in another corner of the room.[if bodycount > 0] There are various corpses lying around the room, looking peaceful in death.[end if][line break][line break]The Cryostasis Hold is aft of here. To the fore stands the double door access to the Lift. To the portside lies the Crew Quarters, and starboard lie the Passenger's Quarters."

The Passengers' Quarters is a room. The Passengers' Quarters is starboard of the Commons. "The Passenger's quarters features rows of bunk beds, storage lockers for each of them, with bathrooms along the walls. Families are grouped together, with adult groups and lone passengers in a different section. The accomadations are pretty sparse, as the passengers are assumed to be in Cryo for the majority of the journey.[line break][line break]The Commons is port of here."

The Crew Quarters is a room. It is port of the Commons. "The Crew Quarters are a bit more spruced up than the passengers. Seeing as this was a research voyage, there's not enough Cryo space for the crew, and they are expected to live here. The room is sectioned off via 3/4 height walls into doubles about twice the size of an office cubicle. Bunks are more comfortable than the passenger's but still nothing approaching luxury.[line break][line break]The Commons is starboard of here."

[Third floor]

The Engine Bay 1 is a room. The Engine Bay 1 is starboard of EB1 Door. "This bay contains one of two primary engines for the ship. The ship is designed in such a manner that even in the event of a complete failure of one engine, the ship is still operational on some level in any normal situation it would be expected to be in. There is a space for an anti-matter fuel capsule to be manually inserted.[line break][line break]Engineering is port of here."

The Engine Bay 2 is a room. The Engine Bay 2 is port of EB2 Door. "This bay contains one of two primary engines for the ship. The ship is designed in such a manner that even in the event of a complete failure of one engine, the ship is still operational on some level in any normal situation it would be expected to be in. There is a space for an anti-matter fuel capsule to be manually inserted.[line break][line break]In one corner, a space has been created to harber an incubation chamber, with some of the engine's power being redirected to the device. Attached are various pieces of monitoring equipment. Inside are the remains of an egg the size of a beach ball.[if note pad is in engine bay 2] A [note pad] lies in the corner, barely visible under one of the monitors.[end if][line break][line break]Engineering is starboard of here."

Engineering is a room. "Engineering is an expansive room with a multitude of purposes, including scientific research, and materials fabrication. There are various fabrication machines in one corner, and Herman's AI core takes up a sizeable chunk of the depressed center area. [if the plans are in engineering]Next to the fabrication machines there is a selection of predesigned [plans].[end if][line break][line break]Engine Bay 1 is starboard, and Engine Bay 2 is portside. The Lift is fore."

[Bottom floor]

The Cargo Bay is a room. The Cargo Bay is fore of the Airlock. "General purpose storage facility. With space access, for all your spacing needs.[line break][line break]The Lift is fore, the airlock is aft."

Outer Space is a room. Outer Space is aft of the Airlock. "Space... it seems to go on forever, until you get to the end and there's a gorilla chucking barrels at you! If you managed to get outside the ship you broke something, congratulations! Try 'undo' until you're back in the ship."

[Central Lift]

The Central Lift 1F is a room. It is aft of the CQ Door and port of the DH Door. "You've arrived topside. The first floor houses all the main command facilities necessary to run the ship. [line break][line break]The Captain's Quarters is fore of here and the Dining Hall is starboard. You can take the elevator down to the second floor."

The Central Lift 2F is a room. It is fore of the Commons and below the Central Lift 1F. "The second floor is host to the sleeping quarters for both crew and passengers. Additionally, the Cryostasis Bay can be found towards the stern.[line break][line break]The Commons is aft of here. You can take the elevator up to the first floor, or down to the third."

The Central Lift 3F is a room. It is fore of Engineering and below the Central Lift 2F. "The third floor, otherwise called the Engineering floor, is home to the systems that run and fly the ship. Inclusive of the engine bays, Herman's AI core is secured on this floor as well.[line break][line break]Engineering is aft of here. You can take the elevator up to the second floor, or down to the fourth."

The Central Lift 4F is a room. It is fore of the Cargo Bay and below the Central Lift 3F. "The lowest floor is the Cargo Bay, located here at the stern for ease of access when docking. The large airlock door may be malfunctional, locking the elevator door in the event.[line break][line break]The Cargo Bay is aft of here. You can take the elevator up to the third floor."

When play begins:

say "TUTORIAL: Words written in *asterisks* are specific actions that the player should take. Because you are in a space ship, cardinal directions don't make sense, and they are replaced with Fore/Aft, and Port/Starboard.[line break][line break]An abhorrent hissing sound reverberates throughout your body. A lingering chill eases into a familiar lukewarmth as the sound of air whistling out of a small hole ushers you to open your eyes. You catch a glimpse of frost clinging onto the military-grade glass panel in front of you slowly melting away. A display projected onto the glass flashes the word 'Depressurizing' incessantly until the hissing dissipates.[line break][line break]Two heavy clicks are heard, the panel in front of you begins to remove itself and provide you escape from your confinement. A third clunk freezes the hatch in its tracks, leaving a small gap between the mechanism's seams. You can see steel floor panels through the gap connecting you to the environment outside. As feeling is returned rightfully to your limbs, you forcefully kick the hatch open, sending the door into the wall opposite you. Surprised at how easy it was to break out of your capsule, you ponder the amount of time that has passed.[line break][line break]As you step out of your hold, you notice the dim illumination of the room. Albeit the room is nigh pitch black, you make out the painted 'Cryostasis Block D' on the large steel grey wall ahead."

After taking EB2 Key:

say "You found a digital key to Engine Bay 2.";

Now the EB2 Door is unlocked.

The player is in the Cryostasis Hold.